Viewports locken & unlocken

[Markske]

Hoi,

ik vroeg me af of er misschien een knopje zou bestaan om viewports te locken en te unlocken? Of moet je telkens naar het Properties-menu gaan?

Alvast bedankt!!!
Markske

[Joop]

Zelf Maken? 

[Markske]

Zelf Maken? 

is inderdaad een mogelijkheid 
alleen vind ik nergens het commando terug om viewports te locken en te unlocken 
(of moet het misschien via Lisp gebeuren?)

[Markske]

Sorry, te snel gereageerd 

-VPORTS
[ON/OFF/Fit/Shadeplot/Lock/Object/Polygonal/Restore/2/3/4]

ik kan verder 

Thanks anyway!!!

Greetz,
Markske

ps: hier voor de volledigheid:

^C^C-vports;lock;on;
^C^C-vports;lock;off;

[Gene]

Wanneer de tekening in paperspace staat klik ik op de Vport zodat er grips opstaan. dan klik je met de rechermuisknop, er verschijnt een screenmenu waar je de optie "Display Locked" vindt, je kiest hier voor "yes of no"

Zo doe ik het

[j-o-s]

met een button is het veel makelijker en sneller zeker als je er een groot aantal moet hebt

j-o-s

[Reimer]

Ik heb onderstaande regels in een lisp gezet. Nu heb ik een commando VL om alle aanwezige viewports te LOCKEN en VU om ze te UNLOCKEN. Dit werkt lekker snel.

; -vports -> lock -> all
(defun C:vl ()
    (command "-vports" "lock" "on" "all" "")
    (prompt "        Alle viewports zijn LOCKED")
  (princ)
)

; -vports -> unlock -> all
(defun C:vu ()
    (command "-vports" "lock" "off" "all" "")
    (prompt "        allee viewports zijn UNlocked")
  (princ)
)

[j-o-s]

dit is nog beter

[Markske]

Prachtig!!! 

Many thanks Reimer 

Greetz,
Markske

[VDZS]

Na meer dan 10 jaar nog een vraagje...

Kan men lisp ook laten uitbreiden naar meerdere layouts (tabs)?

Grts

J.

[cadtools@gmail.com]

Hmmm..
Ik gebruik ook een 'lock / unlock all' macro onder een knop
Maar dit werkt volgens mij alleen in een (1!) actieve layout.

Hans
Niet achter pc zittende..

[roy_043]

... uitbreiden naar meerdere layouts (tabs)?

Code Selecteer Uitklappen

(defun VportsLockAll (lockP / doc)
  (vl-load-com)
  (setq doc (vla-get-activedocument (vlax-get-acad-object)))
  (vla-endundomark doc) ; Just in case.
  (vla-startundomark doc)
  (vlax-for lyt (vla-get-layouts doc)
    (vlax-for obj (vla-get-block lyt)
      (if (vlax-property-available-p obj 'displaylocked)
        (vla-put-displaylocked obj (if lockP :vlax-true :vlax-false))
      )
    )
  )
  (vla-endundomark doc)
)

(defun c:VPLO ()
  (VportsLockAll T)
  (princ)
)

(defun c:VPUN ()
  (VportsLockAll nil)
  (princ)
)

[VDZS]

THX roy_043! 
Werkt perfect!

[roy_043]

Verbeterde versie (de 'Model' tab wordt niet meer geanalyseerd):

Code Selecteer Uitklappen

(defun VportsLockAll (lockP / doc)
  (vl-load-com)
  (setq doc (vla-get-activedocument (vlax-get-acad-object)))
  (vla-endundomark doc)
  (vla-startundomark doc)
  (vlax-for lyt (vla-get-layouts doc)
    (if (= :vlax-false (vla-get-modeltype lyt))
      (vlax-for obj (vla-get-block lyt)
        (if (vlax-property-available-p obj 'displaylocked)
          (vla-put-displaylocked obj (if lockP :vlax-true :vlax-false))
        )
      )
    )
  )
  (vla-endundomark doc)
)

(defun c:VPLO ()
  (VportsLockAll T)
  (princ)
)

(defun c:VPUN ()
  (VportsLockAll nil)
  (princ)
)

[VDZS]

Thx Roy_043! 

Werkt perfect!